Source Member: QDDSSRC,FDXAVTD
*T: FedEx Address Verification
*I: QCMPSRC,CRTDSPF
*================================================================
A INDARA
A DSPSIZ(24 80 *DS3)
A CA03(03 'Exit')
A CA05(05 'Refresh')
A CA12(12 'Cancel')
A PRINT
*================================================================
*?SFLRCD - Subfile record
*================================================================
A R SFLRCD SFL
*
A ATTR 1A P
* Hidden address
A RADDR 489A H
A SFLSEL 1A B 10 3
A DTAVAL 72A O +3DSPATR(&ATTR)
*================================================================
*?SFLCTL - Subfile control
*================================================================
A R SFLCTL SFLCTL(SFLRCD)
A SFLSIZ(10)
A SFLPAG(10)
A OVERLAY
A 81 SFLDSP
A 82 SFLDSPCTL
A N82 SFLCLR
A N84 SFLEND(*MORE)
A RRN 4S 0H SFLRCDNBR
*
A 1 34'Verify Address'
A DSPATR(HI)
A 3 2'Type option, press Enter.'
A COLOR(BLU)
A 4 4'1=Select 5=Display'
A COLOR(BLU)
A 6 2'==>'
A SELADR 72A O +2DSPATR(HI)
A 9 2'Opt Address'
A DSPATR(HI)
*================================================================
*?DETAIL - Detail screen
*================================================================
A R DETAIL
A OVERLAY
*
A MODE 1A P
A SCORE 4A H
A RANK 5A H
A HOUSE 10A H
A 1 34'Verify Address'
A DSPATR(HI)
A 5 2'Company. . . . . . :'
A COMPANY 35A B +2DSPATR(&MODE) CHECK(LC)
A 6 2'Address. . . . . . :'
A LINE1 35A B +2DSPATR(&MODE) CHECK(LC)
A 7 2' '
A LINE2 35A B +2DSPATR(&MODE) CHECK(LC)
A 8 2'City . . . . . . . :'
A CITY 35A B +2DSPATR(&MODE) CHECK(LC)
A 9 2'State/Zip. . . . . :'
A STATE 2A B +2DSPATR(&MODE)
A ZIPCODE 10A B +2DSPATR(&MODE)
A 11 2'Urbanization (PR). :'
A URBNAME 35A B +2DSPATR(&MODE) CHECK(LC)
A RESIDENCE 4A H
A SERRTYPE 16A H
A ERRDATA 320A O 14 1DSPATR(HI)
*================================================================
*?CMDKEY - Subfile command keys
*================================================================
A R CMDKEY
A BLINK
A 23 2'F3=Exit F5=Refresh F12=-
A Cancel'
A COLOR(BLU)
*=========================================================================
*?MSGRCD - Message subfile record
*================================================================
A R MSGRCD SFL
A SFLMSGRCD(24)
A MSGKEY SFLMSGKEY
A PGMNAM SFLPGMQ
*=========================================================================
*?MSGCTL - Message subfile control
*================================================================
A R MSGCTL SFLCTL(MSGRCD)
A SFLPAG(01) SFLSIZ(03)
A OVERLAY
A SFLINZ SFLDSP SFLDSPCTL
A 25
AON25 SFLEND
A PGMNAM SFLPGMQ